ZSH configuration

I wanted to reconfigure the my zsh setup.

Before, I was using Oh My ZSH. Which is a wonderful configuration framework for zsh.

The problem I had was not using the feature that it provided. I was only using the base configuration and two plugins: git and sudo. Also, I didn’t use any theme since I prefer the starship prompt.

I wanted to strip down the configuration and remove this dependency. So I looked at the omz configurations and man zsh(1) to came up with the following configuration. Another source was the prezto framework, that you could look at for an alternative to omz.

# Return if not run interactively
[[ $- != *i* ]] && return

##
# Env variables
#
# Cache directory
ZSH_CACHE_DIR="$XDG_CACHE_HOME/zsh"
# Specify comp dump direcory
ZSH_COMPDUMP="$ZSH_CACHE_DIR/zcompdump"
# FPath
#export FPATH="$FPATH:$XDG_DATA_HOME/zsh"
fpath+=$XDG_DATA_HOME/zsh
# List colors
LS_COLORS=${LS_COLORS:-'di=34:ln=35:so=32:pi=33:ex=31:bd=36;01:cd=33;01:su=31;40;07:sg=36;40;07:tw=32;40;07:ow=33;40;07:'}

# History
HISTFILE="$ZSH_CACHE_DIR/zsh_history"
HISTSIZE=50000
SAVEHIST=10000

if [ ! -f "$ZSH_CACHE_DIR" ]; then
    mkdir -p "$ZSH_CACHE_DIR"
fi

##
# Zsh functions
#
# Remove default prompt
autoload -U promptinit && promptinit && prompt off
# Move with regex
autoload -U zmv
# Jump
autoload -U j

##
# Zsh options
#
# Share history between shells
setopt share_history
# Try to correct commands
setopt correct

# History
setopt extended_history
setopt hist_expire_dups_first
setopt hist_verify

##
# Completion
#
# automatically load bash completion functions
# autoload -U +X bashcompinit && bashcompinit -d "$ZSH_COMPDUMP"
# Init completion
autoload -U compinit && compinit -C -d "$ZSH_COMPDUMP"

zmodload -i zsh/complist

# show completion menu on successive tab press
setopt always_to_end
setopt auto_list
setopt auto_menu
setopt auto_param_slash
setopt complete_aliases
setopt complete_in_word
setopt extended_glob
setopt path_dirs
# do not autoselect the first completion entry
unsetopt menu_complete
unsetopt flowcontrol
unsetopt CASE_GLOB

#
# Styles
#

# Defaults.
zstyle ':completion:*:default' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*:default' list-prompt '%S%M matches%s'

zstyle ':completion:*' special-dirs true

# Use caching so that commands like apt and dpkg complete are useable
zstyle ':completion::complete:*' use-cache on
zstyle ':completion::complete:*' cache-path "$ZSH_CACHE_DIR/completion"

# Case insensitive
zstyle ':completion:*' matcher-list 'm:{a-zA-Z}={A-Za-z}' 'r:|[._-]=* r:|=*' 'l:|=* r:|=*'

# Group matches and describe.
zstyle ':completion:*:*:*:*:*' menu select
zstyle ':completion:*:matches' group 'yes'
zstyle ':completion:*:options' description 'yes'
zstyle ':completion:*:options' auto-description '%d'
zstyle ':completion:*:corrections' format ' %F{green}-- %d (errors: %e) --%f'
zstyle ':completion:*:descriptions' format ' %F{yellow}-- %d --%f'
zstyle ':completion:*:messages' format ' %F{purple} -- %d --%f'
zstyle ':completion:*:warnings' format ' %F{red}-- no matches found --%f'
zstyle ':completion:*' format ' %F{yellow}-- %d --%f'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' verbose yes

# Fuzzy match mistyped completions.
zstyle ':completion:*' completer _complete _match _approximate
zstyle ':completion:*:match:*' original only
zstyle ':completion:*:approximate:*' max-errors 1 numeric

# Increase the number of errors based on the length of the typed word. But make
# sure to cap (at 7) the max-errors to avoid hanging.
zstyle -e ':completion:*:approximate:*' max-errors 'reply=($((($#PREFIX+$#SUFFIX)/3>7?7:($#PREFIX+$#SUFFIX)/3))numeric)'

# Don't complete unavailable commands.
zstyle ':completion:*:functions' ignored-patterns '(_*|pre(cmd|exec))'

# Array completion element sorting.
zstyle ':completion:*:*:-subscript-:*' tag-order indexes parameters

# Directories
zstyle ':completion:*:*:cd:*' tag-order local-directories directory-stack path-directories
zstyle ':completion:*:*:cd:*:directory-stack' menu yes select
zstyle ':completion:*:-tilde-:*' group-order 'named-directories' 'path-directories' 'users' 'expand'
zstyle ':completion:*' squeeze-slashes true

# History
zstyle ':completion:*:history-words' stop yes
zstyle ':completion:*:history-words' remove-all-dups yes
zstyle ':completion:*:history-words' list false
zstyle ':completion:*:history-words' menu yes

# Environment Variables
zstyle ':completion::*:(-command-|export):*' fake-parameters ${${${_comps[(I)-value-*]#*,}%%,*}:#-*-}

# Populate hostname completion. But allow ignoring custom entries from static
# */etc/hosts* which might be uninteresting.
zstyle -a ':prezto:module:completion:*:hosts' etc-host-ignores '_etc_host_ignores'

zstyle -e ':completion:*:hosts' hosts 'reply=(
  ${=${=${=${${(f)"$(cat {/etc/ssh/ssh_,~/.ssh/}known_hosts(|2)(N) 2> /dev/null)"}%%[#| ]*}//\]:[0-9]*/ }//,/ }//\[/ }
  ${=${(f)"$(cat /etc/hosts(|)(N) <<(ypcat hosts 2> /dev/null))"}%%(\#${_etc_host_ignores:+|${(j:|:)~_etc_host_ignores}})*}
  ${=${${${${(@M)${(f)"$(cat ~/.ssh/config 2> /dev/null)"}:#Host *}#Host }:#*\**}:#*\?*}}
)'

# Don't complete uninteresting users...
zstyle ':completion:*:*:*:users' ignored-patterns \
  adm amanda apache avahi beaglidx bin cacti canna clamav daemon \
  dbus distcache dovecot fax ftp games gdm gkrellmd gopher \
  hacluster haldaemon halt hsqldb ident junkbust ldap lp mail \
  mailman mailnull mldonkey mysql nagios \
  named netdump news nfsnobody nobody nscd ntp nut nx openvpn \
  operator pcap postfix postgres privoxy pulse pvm quagga radvd \
  rpc rpcuser rpm shutdown squid sshd sync uucp vcsa xfs '_*'

# ... unless we really want to.
zstyle '*' single-ignored show

# Ignore multiple entries.
zstyle ':completion:*:(rm|kill|diff):*' ignore-line other
zstyle ':completion:*:rm:*' file-patterns '*:all-files'

# Kill
zstyle ':completion:*:*:*:*:processes' command 'ps -u $LOGNAME -o pid,user,command -w'
zstyle ':completion:*:*:kill:*:processes' list-colors '=(#b) #([0-9]#) ([0-9a-z-]#)*=01;36=0=01'
zstyle ':completion:*:*:kill:*' menu yes select
zstyle ':completion:*:*:kill:*' force-list always
zstyle ':completion:*:*:kill:*' insert-ids single

# Man
zstyle ':completion:*:manuals' separate-sections true
zstyle ':completion:*:manuals.(^1*)' insert-sections true

# Media Players
zstyle ':completion:*:*:mpg123:*' file-patterns '*.(mp3|MP3):mp3\ files *(-/):directories'
zstyle ':completion:*:*:mpg321:*' file-patterns '*.(mp3|MP3):mp3\ files *(-/):directories'
zstyle ':completion:*:*:ogg123:*' file-patterns '*.(ogg|OGG|flac):ogg\ files *(-/):directories'
zstyle ':completion:*:*:mocp:*' file-patterns '*.(wav|WAV|mp3|MP3|ogg|OGG|flac):ogg\ files *(-/):directories'

# Mutt
if [[ -s "$HOME/.mutt/aliases" ]]; then
  zstyle ':completion:*:*:mutt:*' menu yes select
  zstyle ':completion:*:mutt:*' users ${${${(f)"$(<"$HOME/.mutt/aliases")"}#alias[[:space:]]}%%[[:space:]]*}
fi

# SSH/SCP/RSYNC
zstyle ':completion:*:(ssh|scp|rsync):*' tag-order 'hosts:-host:host hosts:-domain:domain hosts:-ipaddr:ip\ address *'
zstyle ':completion:*:(scp|rsync):*' group-order users files all-files hosts-domain hosts-host hosts-ipaddr
zstyle ':completion:*:ssh:*' group-order users hosts-domain hosts-host users hosts-ipaddr
zstyle ':completion:*:(ssh|scp|rsync):*:hosts-host' ignored-patterns '*(.|:)*' loopback ip6-loopback localhost ip6-localhost broadcasthost
zstyle ':completion:*:(ssh|scp|rsync):*:hosts-domain' ignored-patterns '<->.<->.<->.<->' '^[-[:alnum:]]##(.[-[:alnum:]]##)##' '*@*'
zstyle ':completion:*:(ssh|scp|rsync):*:hosts-ipaddr' ignored-patterns '^(<->.<->.<->.<->|(|::)([[:xdigit:].]##:(#c,2))##(|%*))' '127.0.0.<->' '255.255.255.255' '::1' 'fe80::*'


##
# Keymaps
#
# Use vim keybindings
bindkey -v

autoload -Uz edit-command-line
zle -N edit-command-line
bindkey -M vicmd 'vv' edit-command-line

# #
# Autosuggestion
ZSH_AUTOSUGGEST='/usr/share/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh'
if [[ -f $ZSH_AUTOSUGGEST ]]; then
    source $ZSH_AUTOSUGGEST
fi
ZSH_AUTOSUGGEST_HIGHLIGHT_STYLE="fg=white,underline"

##
# Syntax Highlighting
#
ZSH_HIGHLIGHT='/usr/share/zsh-autosuggestions/zsh-autosuggestions.zsh'
if [[ -f $ZSH_HIGHLIGHT ]]; then
    source $ZSH_HIGHLIGHT

    ZSH_HIGHLIGHT_HIGHLIGHTERS=(main brackets)
    # main
    ZSH_HIGHLIGHT_STYLES[unknown-token]='fg=red'
    ZSH_HIGHLIGHT_STYLES[comment]='fg=white,bg=black'
    ZSH_HIGHLIGHT_STYLES[path]='fg=magenta'
    ZSH_HIGHLIGHT_STYLES[path_pathseparator]='fg=magenta,bold'
    ZSH_HIGHLIGHT_STYLES[single-hyphen-option]='fg=yellow'
    ZSH_HIGHLIGHT_STYLES[double-hyphen-option]='fg=yellow'
    ZSH_HIGHLIGHT_STYLES[commandseparator]='fg=cyan'
    # Brackets
    ZSH_HIGHLIGHT_STYLES[bracket-error]='fg=red'
    ZSH_HIGHLIGHT_STYLES[bracket-level-1]='fg=blue'
    ZSH_HIGHLIGHT_STYLES[bracket-level-2]='fg=green'
    ZSH_HIGHLIGHT_STYLES[bracket-level-3]='fg=magenta'
    ZSH_HIGHLIGHT_STYLES[bracket-level-4]='fg=yellow'
    ZSH_HIGHLIGHT_STYLES[bracket-level-5]='fg=cyan'
fi

##
# Aliases
#
source $HOME/.aliasrc
eval "$(direnv hook zsh)"

##
# Starship
#
eval "$(starship init zsh)"

Exploring the zsh options let me fine tune the configuration for my needs, without the overhead required by a framework to satisfy all different needs.

Other resources:

• zsh refcard
• zsh lovers